Setting Up A Shortcut To Open Multiple Programs

[IggyWH]

I did a search but I'm unsure of specific terms so my search was no good. I'm looking for instructions on how to setup a shortcut icon that will open up all my poker apps. If you could point me that way, or tell me what I need to type, I would appreciate it.

[TheIrishThug]

u can get auto hotkey or just us a batch script. either way is pretty simple.

[Mogobu The Fool]

This is actually functionality I'm planning to add to PartyPlanner eventually.

Otherwise, I second the previous recommendations.

[Adde]

Here's my AutoHotkey script for doing this. It will:

* Open Partypoker, click Login, move lobby to upper left, click button to make table list longer.

* Open allSnap.

* Open Pokertracker, start import timer, do a force import, minimize window.

* Start PokerAce Hud minimized.

* Start Auto Resizer, init my preferred settings, move it to secondare monitor, minimize it.

(For Partypoker to work you have to place a shortcut copy (PartyPoker.lnk) in "PartyGaming/PartyPoker" folder.)

Adde

[Adde]

; --------------------------------------------------------------------------------------------
;; PARTYPOKER ;;

SetTitleMatchMode, 1
Process, Exist, PartyGaming.exe
if %ErrorLevel% = 0
{
Run, C:\Program\PartyGaming\PartyPoker\PartyPoker.lnk

WinWait, PartyPoker.com: Poker Lobby
WinActivate, PartyPoker.com: Poker Lobby

WinMove, PartyPoker.com: Poker Lobby, , 0, 0
ControlClick , AfxWnd4262 , PartyPoker.com: Poker Lobby

WinWait, PartyAccount Login
WinActivate, PartyAccount Login

Send {TAB}
Send {TAB}
Send {TAB}
Send {SPACE}

}
else
{
WinMove, PartyPoker.com: Poker Lobby, , 0, 0
ControlClick , AfxWnd4262 , PartyPoker.com: Poker Lobby
}
; --------------------------------------------------------------------------------------------



; --------------------------------------------------------------------------------------------
;; ALLSNAP ;;

Process, Exist, allSnap.exe
if %ErrorLevel% = 0
{
Run, "C:\Program\allSnap\allSnap.exe"
}
; --------------------------------------------------------------------------------------------



; --------------------------------------------------------------------------------------------
;; POKERTRACKER ;;

SetTitleMatchMode, 1

Process, Exist, ptrack2.exe
if %ErrorLevel% = 0
{
Run, "C:\Program\Poker Tracker V2\ptrack2.exe", ,max

}

openImport := 0
startImport := 0

IfWinExist, Poker Tracker (Version, Auto-Import Party
{
}
else
{
openImport := 1
}

if openImport = 1
{

WinWait, Poker Tracker (Version
WinActivate, Poker Tracker (Version
WinMenuSelectItem, Poker Tracker, , File, Auto-Import Party
WinWait, Poker Tracker (Version
startImport := 1
}

if startImport = 1
{
WinActivate, Poker Tracker (Version
WinWait, Poker Tracker (Version
Send {TAB}
Send {TAB}
Send {TAB}
Send {TAB}
Send {TAB}
Send {TAB}
Send {TAB}
Send {TAB}
Send {SPACE}
Send {TAB}
Send {SPACE}
WinWait, Poker Tracker (Version, Stop Timer
}

WinMinimize, Poker Tracker (Version

; --------------------------------------------------------------------------------------------



; --------------------------------------------------------------------------------------------
;; POKERACE HUD ;;

Process, Exist, PAHud.exe
if %ErrorLevel% = 0
{
Run, "C:\Program\PokerAce Hud\PAHud.exe", ,min
}
; --------------------------------------------------------------------------------------------



; --------------------------------------------------------------------------------------------
;; AUTO-RESIZER ;;

SetTitleMatchMode, 1
Process, Exist, Party Beta Auto Resizer.exe
if %ErrorLevel% = 0
{
Run, "C:\Documents and Settings\Adde\Mina dokument\# POKER\Party_Beta_Auto_Resizer_v07b\Party Beta Auto Resizer.exe"

WinWait, Auto-Resizer
WinClose, Auto-Resizer

WinWait, Auto-Resizer
WinActivate, Auto-Resizer

Send {SPACE}
Send {TAB}
Send {TAB}
Send {TAB}
Send {SPACE}
Send {TAB}
Send {TAB}
Send {SPACE}
Send {TAB}
Send {TAB}
Send {SPACE}
Send {TAB}
Send {SPACE}

WinMove, Auto-Resizer, , 1600, 0
WinWait, Auto-Resizer
WinMinimize, Auto-Resizer
}
; --------------------------------------------------------------------------------------------

[TheNoocH]

here's a quick batch file
1) open up notepad
2) paste in this code (add/remove/change based upon what you want to open)

@echo off
cd "c:\program files\poker tracker v2"
start ptrack2.exe
cd "c:\program files\pokerstove"
start pokerstove.exe

3) save as whatever name you like with a .bat extension
4) create a shortcut on your desktop or wherever you like
5) waaaaalllllaaaaahhhhhh....you're done...

hope it helps


****PS*****
adde...just so i know...how do you run the AHK script? any easy directions or how to modify for stars? i keep seeing the AHK scripts posted but don't have any idea what to do with them...thanks...

[jukofyork]

Hey, I think I will borrow this until I get time to add the ability to remember settings for AutoResizer.

Never thought about making a AHK script to open all the poker utils, but this looks pretty good idea! [img]/images/graemlins/smile.gif[/img]

Juk [img]/images/graemlins/smile.gif[/img]

[Adde]

This is fun stuff. I tweaked my script with configuration stuff to choose what programs should start, what site import shuld be started in Pokertracker, what settings should be set in Auto Resizer, and some other stuff. Steal away!

Adde

[Adde]

; --------------------------------------------------------------------------------------------
;
; AutoHotkey script for opening a bunch of poker applications at once.
;
;
; Current Bugs:
;
; - Don't work if PokerTracker dialog for updated version pops up.
; - Don't work if PokerAce Hud dialog for updated version pops up.
; - Don't work if PokerStars news dialog pops up.
;
; --------------------------------------------------------------------------------------------



; --------------- Path Settings
;
; Leave path blank ("") if you don't want to open a specific program.
;

pathPartyPoker := "C:\Program\PartyGaming\PartyPoker\PartyPoker. lnk"
pathPokerStars := "C:\Program\PokerStars\PokerStarsUpdate.exe"
pathPokerTracker := "C:\Program\Poker Tracker V2\ptrack2.exe"
pathAllSnap := "C:\Program\allSnap\allSnap.exe"
pathPokerAce := "C:\Program\PokerAce Hud\PAHud.exe"
pathAutoResizer := "C:\Program\Party_Beta_Auto_Resizer_v07b\Party Beta Auto Resizer.exe"


; --------------- PartyPoker Settings

ppMoveWindowToX := 0 ; [-1=no move]
ppMoveWindowToY := 0

ppLobbyView := "expand" ; [normal/expand/zoom]


; --------------- PokerStars Settings

psMoveWindowToX := 0 ; [-1=no move]
psMoveWindowToY := 0


; --------------- PokerTracker Settings

ptWhatSiteToImport := "partypoker" ; [partypoker/pokerstars]
ptTimerMinutes := 2

ptMinimize := 1 ; [1=YES/0=NO]


; --------------- PokerAce Hud Settings

paMinimize := 1 ; [1=YES/0=NO]


; --------------- Auto Resizer Settings

arMoveWindowToX := 1600 ; [-1=no move]
arMoveWindowToY := 0

arMinimize := 1 ; [1=YES/0=NO]

arPrefsWaitingList := 1 ; [1=YES/0=NO]
arPrefsFirstAvailable := 1
arPrefsWaitForBb := 0
arPrefsPost1stBb := 0
arPrefsBuyIn := 1
arPrefsNoSpam := 1
arPrefsMinimizeHh := 0
arPrefsCheckFoldOn := 0
arPrefsLockSize := 0
arPrefsHideMoney := 0



;
;
;
; DO ONLY CHANGE SETTINGS ABOVE THIS LINE
;
;
; DO NOT CHANGE ANYTHING BELOW THIS LINE
;
;
;



; --------------------------------------------------------------------------------------------
;
; SYSTEM VARIABLES
;
; --------------------------------------------------------------------------------------------

sysArTxtLicense := "Auto-Resizer: Freeware"
sysArTxtTitle := "Auto-Resizer"
sysArTxtTitleKey := "[Auto] Buy-in"

sysPsTxtFirst := "Network Status"
sysPsTxtLobby := "PokerStars Lobby"
sysPsTxtLogin := "Login"
sysPsTxtLoginKey := "User ID"

sysPpTxtLobby := "PartyPoker.com: Poker Lobby"
sysPpTxtLogin := "PartyAccount Login"
sysPpTxtLoginKey := "Account Name"

sysPtTxtTitle := "Poker Tracker (Version"
sysPtTxtImport := "Auto-Import"


sysPpProcessName := "PartyGaming.exe"
sysPsProcessName := "PokerStars.exe"
sysPtProcessName := "ptrack2.exe"
sysPaProcessName := "PAHud.exe"
sysArProcessName := "Party Beta Auto Resizer.exe"
sysAsProcessName := "allSnap.exe"




; --------------------------------------------------------------------------------------------
;
; PARTYPOKER
;
; --------------------------------------------------------------------------------------------

if (pathPartyPoker <> "")
{

SetTitleMatchMode, 1
Process, Exist, %sysPpProcessName%
if (%ErrorLevel% = 0) {
Run, %pathPartyPoker%

WinWait, %sysPpTxtLobby%
WinActivate, %sysPpTxtLobby%
if (ppMoveWindowToX >= 0)
WinMove, %sysPpTxtLobby%, , ppMoveWindowToX , ppMoveWindowToY

if (ppLobbyView = "zoom")
className := "AfxWnd4263"
else if (ppLobbyView = "expand")
className := "AfxWnd4262"
else
className := "AfxWnd4261"

WinWait, %sysPpTxtLobby%
WinActivate, %sysPpTxtLobby%
ControlClick , %className% , %sysPpTxtLobby%

WinWait, %sysPpTxtLogin%
WinActivate, %sysPpTxtLogin%
ControlClick, Button2 , %sysPpTxtLogin% , %sysPpTxtLoginKey%
}

}
; ---------- END




; --------------------------------------------------------------------------------------------
;
; POKERSTARS
;
; --------------------------------------------------------------------------------------------

if (pathPokerStars <> "")
{

SetTitleMatchMode, 1
Process, Exist, %sysPsProcessName%
if (%ErrorLevel% = 0) {
Run, %pathPokerStars%
WinWait, , %sysPsTxtFirst%
Loop {
IfWinNotExist , , %sysPsTxtFirst%
break
}
WinWait, %sysPsTxtLobby%
if (psMoveWindowToX >= 0)
WinMove, %sysPsTxtLobby%, , psMoveWindowToX , psMoveWindowToY
WinActivate, %sysPsTxtLobby%
WinMenuSelectItem, %sysPsTxtLobby%, , Lobby , Login
SetTitleMatchMode, 2
WinWait, %sysPsTxtLogin% , %sysPsTxtLoginKey%
ControlClick, Button4 , %sysPsTxtLogin% , %sysPsTxtLoginKey%
}

}
; ---------- END




; --------------------------------------------------------------------------------------------
;
; POKERTRACKER
;
; --------------------------------------------------------------------------------------------

if (pathPokerTracker <> "")
{

SetTitleMatchMode, 1
Process, Exist, %sysPtProcessName%
if (%ErrorLevel% = 0) {
Run , %pathPokerTracker% , , max
}

if (ptWhatSiteToImport = "partypoker") {
txtMenu := "Auto-Import Party"
txtWindow := "Auto-Import Party"
btnStart := "Button12"
btnForce := "Button11"
editMins := "PBEDIT701"
}
if (ptWhatSiteToImport = "pokerstars") {
txtMenu := "Auto-Import PokerStars"
txtWindow := "Auto-Import PokerStars"
btnStart := "Button11"
btnForce := "Button12"
editMins := "PBEDIT701"
}

openWindow := 0
startTimer := 0

IfWinNotExist, %sysPtTxtTitle%, %sysPtTxtImport%
{
openWindow := 1
}
if (openWindow = 1) {
WinWait, %sysPtTxtTitle%
WinActivate, %sysPtTxtTitle%
WinMenuSelectItem, %sysPtTxtTitle%, , File, %txtMenu%
startTimer := 1
}
if (startTimer = 1) {
WinWait, %sysPtTxtTitle% , Start Timer
ControlSetText , %editMins% , %ptTimerMinutes% , , Start Timer
ControlClick, %btnStart%, , Start Timer
WinWait, %sysPtTxtTitle%, Stop Timer
ControlClick, %btnForce%, , Force Import
}
if (ptMinimize = 1) {
WinMinimize, %sysPtTxtTitle%
}

}
; ---------- END




; --------------------------------------------------------------------------------------------
;
; POKERACE HUD
;
; --------------------------------------------------------------------------------------------

if (pathPokerAce <> "")
{

Process, Exist, %sysPaProcessName%
if (%ErrorLevel% = 0) {
if (paMinimize)
Run, %pathPokerAce% , , min
else
Run, %pathPokerAce%

}

}
; ---------- END




; --------------------------------------------------------------------------------------------
;
; AUTO RESIZER
;
; --------------------------------------------------------------------------------------------

if (pathAutoResizer <> "")
{

SetTitleMatchMode, 1
Process, Exist, %sysArProcessName%
if (%ErrorLevel% = 0) {
Run, %pathAutoResizer%

WinWait, %sysArTxtLicense%
WinClose, %sysArTxtLicense%

WinWait, %sysArTxtTitle% , %sysArTxtTitleKey%
WinActivate, %sysArTxtTitle% , %sysArTxtTitleKey%

ControlClick, Button1 , %sysArTxtTitle% , %sysArTxtTitleKey%

if (arPrefsWaitingList = 1)
ControlClick, Button13 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsFirstAvailable = 1)
ControlClick, Button15 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsWaitForBb = 1)
ControlClick, Button4 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsPost1stBb = 1)
ControlClick, Button7 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsBuyIn = 1)
ControlClick, Button5 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsNoSpam = 1)
ControlClick, Button16 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsMinimizeHh = 1)
ControlClick, Button18 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsCheckFoldOn = 1)
ControlClick, Button17 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsLockSize = 1)
ControlClick, Button3 , %sysArTxtTitle% , %sysArTxtTitleKey%
if (arPrefsHideMoney = 1)
ControlClick, Button14 , %sysArTxtTitle% , %sysArTxtTitleKey%

WinWait, %sysArTxtTitle% , %sysArTxtTitleKey%
if (arMoveWindowToX >= 0)
WinMove, %sysArTxtTitle%, , arMoveWindowToX , arMoveWindowToY
if (arMinimize = 1) {
WinWait, %sysArTxtTitle%
WinMinimize, %sysArTxtTitle%
}
}

}
; ---------- END




; --------------------------------------------------------------------------------------------
;
; ALLSNAP
;
; --------------------------------------------------------------------------------------------

if (pathAllSnap <> "")
{

Process, Exist, %sysAsProcessName%
if (%ErrorLevel% = 0) {
Run, %pathAllSnap%
}

}
; ---------- END

[TheNoocH]

Adde/Sam/anyone who wants to help,

trying this at home...ALMOST got it...couple of quick questions:

1) ControlClick, Button13 --> how do you know what Button # to use? note: this is just an example...i'm more interested how do you find what button in general
eg...i used this in Stars
ControlClick, OK , Login , User ID
ie using OK rather than Button#...just tried it...and seems to work...curious what should be used.

2)WinMinimize --> for Poker Tracker i have it set to minimize to system tray in poker trackers options but this seems to only minimize to task bar. any way to get it to minimize to the system tray?

3) i noticed on the RUN lines that the min and/or max don't seem to work all the time? any reasons why?

4)Is there any way to step through (ie debug) the ahk code? sometimes it just seems to stop processing...

5)can you take a look at this code and see if you see anything that could be better...i had to remark out the part in stars about the network status ...i'm assuming b/c i have to wait till the batch file window closes before i start doing the other menu commands, etc?

thanks for all your help....didn't notice the new code...this is based off your previous code examples...

; CODE BEGINS

pathPokerstars := "C:\Program Files\PokerStars\PS.bat"
pathPokerTracker := "C:\Program Files\Poker Tracker V2\ptrack2.exe"

doMinimizePokerTracker := 1 ; 1=YES 0=NO



; --------------------------------------------------------------------------------------------
;; THUNDERBIRD EMAIL ;;

Process, Exist, Thunderbird.exe
if %ErrorLevel% = 0
{
Run, "C:\Program Files\Mozilla Thunderbird\thunderbird.exe", ,min


SetTitleMatchMode, 2

WinWait, Thunderbird
IfWinNotActive, Thunderbird, , WinActivate, Thunderbird,
WinWaitActive, Thunderbird,

WinMinimize, Thunderbird
}
; --------------------------------------------------------------------------------------------


; --------------------------------------------------------------------------------------------
;; POKERTRACKER ;;
; --------------------------------------------------------------------------------------------

SetTitleMatchMode, 1
Process, Exist, ptrack2.exe
if %ErrorLevel% = 0
{
Run , %pathPokerTracker% , , max
}

openImportWindow := 0
startImportTimer := 0

IfWinNotExist, Poker Tracker (Version, Auto-Import
{
openImportWindow := 1
}
if openImportWindow = 1
{
WinWait, Poker Tracker (Version
WinActivate, Poker Tracker (Version
WinMenuSelectItem, Poker Tracker, , File, Auto-Import PokerStars
startImportTimer := 1
}
if startImportTimer = 1
{
WinWait, Poker Tracker (Version , Start Timer
ControlClick, Button11 , , Start Timer
WinWait, Poker Tracker (Version, Stop Timer
ControlClick, Button12 , , Force Import
}
if doMinimizePokerTracker
{
WinMinimize, Poker Tracker (Version
}
; --------------------------------------------------------------------------------------------


; --------------------------------------------------------------------------------------------
;; POKERACE HUD ;;

Process, Exist, PAHud.exe
if %ErrorLevel% = 0
{
Run, "C:\Program Files\PokerAce Hud\PAHud.exe", ,min
}
; --------------------------------------------------------------------------------------------


; --------------------------------------------------------------------------------------------
;; POKERSTARS ;;
; --------------------------------------------------------------------------------------------

SetTitleMatchMode, 1
Process, Exist, PokerStars.exe
if %ErrorLevel% = 0
{
Run, %pathPokerstars%

WinWait, C:\WINDOWS\system32\cmd.exe
WinWaitClose ; Wait for the exact window found by WinWait to be closed.


;WinWait, , Network Status

;Loop {
;IfWinNotExist , , Network Status
;break
;}

WinWait, PokerStars Lobby
IfWinNotActive, PokerStars Lobby, , WinActivate, PokerStars Lobby,
WinWaitActive, PokerStars Lobby,

;WinMove, PokerStars Lobby, , 0, 0

WinMenuSelectItem, PokerStars Lobby, , Lobby , Login
SetTitleMatchMode, 2
WinWait, Login , User ID
ControlClick, OK , Login , User ID
WinMenuSelectItem,PokerStars Lobby,,Options ,Images
WinMenuSelectItem,PokerStars Lobby,,Options,Images

ControlClick, x422 y146, PokerStars Lobby
ControlClick, x142 y179, PokerStars Lobby
ControlClick, x317 y205, PokerStars Lobby

}
; --------------------------------------------------------------------------------------------





; CODE ENDS