Chip Reloader (New AHK Script) (Reloads at Party and Stars)

[aislephive]

[ QUOTE ]
I a no expert and I am using an older version of the script but for party, I altered2 instances of AfxWnd421 to AfxWnd42u1 and it worked.

I think party has renamed the button, hence the extra "u"

good luck

t

[/ QUOTE ]

Can you post the full working script? Thanks.

[TJD]

As I said I am no ahk expert but the script seems to call the reload routine twice so that is probably why [img]/images/graemlins/smile.gif[/img]

I assumed that it was done for some reason I do not understand. [img]/images/graemlins/confused.gif[/img]

The script I am using is much simplified from the one shown on this thread but you are welcome to it:-

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Code begins here ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;------------------------------------------------------------------------------------------------
; Chip Reloader v0.11
;------------------------------------------------------------------------------------------------
; Date: 2006-05-23
; AHK version: 1.0.44.01
;------------------------------------------------------------------------------------------------
; Author(s): Adde @ 2+2 forums
; Contact: HstreamPoker at gmail dot com
;------------------------------------------------------------------------------------------------
; Reload chips on all Partypoker and Pokerstars tables with just one click.
; See web page for more details.
;
; http://overcards.com/wiki/moin.cgi/ChipReloader
;
; All rights reserved. Use at your own risk.
;------------------------------------------------------------------------------------------------

;_________________________________________________ _______________________________________________
;
; EDIT THESE SETTINGS
;_________________________________________________ _______________________________________________

; Set what hotkeys should perform the reload. Leave blank to not use this function as a hotkey.
; List of available hotkeys: http://www.autohotkey.com/docs/KeyList.htm

cr_hotkey_reload = F6

; Set if Party and/or Stars reload should be performed (1) or not (0).

cr_reload_party = 1
cr_reload_stars = 0

;_________________________________________________ _______________________________________________
;
; DO NOT EDIT BELOW HERE
;_________________________________________________ _______________________________________________

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; auto-execute ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#NoEnv
#SingleInstance Ignore
#Persistent

cr_scriptpad_command_header = Chip Reloader
cr_scriptpad_command_name = Reload All Tables
cr_scriptpad_command_label = CR_ReloadAll_Label
cr_scriptpad_command_enabled = 1

cr_web_page = http://overcards.com/wiki/moin.cgi/PokerReloader

Hotkey, %cr_hotkey_reload%, CR_ReloadAll_Label, UseErrorLevel

goto CR_Scriptpad_End

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; labels ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

CR_ReloadAll_Label:
CR_ReloadAll()
return

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

CR_ReloadAll()
{
global
if (cr_reload_party)
CR_ReloadParty()
if (cr_reload_stars)
CR_ReloadStars()
SoundBeep, , 50
}

CR_ReloadParty()
{
SetTitleMatchMode, 2
WinGet, idList, list, Good Luck ahk_class #32770, , PartyPoker.com:
Loop, %idList%
{
winID := idList%a_index%
CR_ReloadPartyTable(winID)
}
}

CR_ReloadPartyTable(winID)
{
ControlGet, result, Visible, , AfxWnd42u1, ahk_id %winID%
if (not result)
return
ControlGet, result, Visible, , Button5, ahk_id %winID%
if (not result)
return
ControlClick, AfxWnd42u1, ahk_id%winID%
sleep, 300
IfWinExist, PartyPoker.com ahk_class #32770, You can have maximum
{
WinClose, PartyPoker.com ahk_class #32770, You can have maximum
return
}

WinWait, Buy-In ahk_class #32770, , 2
if (ErrorLevel <> 0)
return
WinActivate, Buy-In ahk_class #32770
ControlFocus, Button1, Buy-In ahk_class #32770
SendInput {SPACE}
sleep 300

IfWinExist, PartyPoker.com ahk_class #32770, Please enter an amount
{
WinClose, PartyPoker.com ahk_class #32770, Please enter an amount
WinClose, Buy-In ahk_class #32770
return
}
IfWinExist, PartyPoker.com ahk_class #32770, You can bring a maximum
{
WinClose, PartyPoker.com ahk_class #32770, You can bring a maximum
WinClose, Buy-In ahk_class #32770
return
}

WinWaitClose, Buy-In ahk_class #32770, , 2
Loop
{
IfWinNotExist, Buy-In ahk_class #32770
return
WinActivate, Buy-In ahk_class #32770
ControlFocus, Button1, Buy-In ahk_class #32770
SendInput {SPACE}
WinWaitClose, Buy-In ahk_class #32770, , 1
}

WinWait, PartyPoker.com, Additional chips, 1
if (ErrorLevel <> 0)
return
ControlFocus, Button1, PartyPoker.com, Additional chips
SendInput {SPACE}
WinWaitClose, PartyPoker.com, Additional chips, 2
Loop
{
IfWinNotExist, PartyPoker.com, Additional chips
return
ControlFocus, Button1, PartyPoker.com, Additional chips
SendInput {SPACE}
WinWaitClose, PartyPoker.com, Additional chips, 2
}
}

CR_ReloadStars()
{
SetTitleMatchMode, 2
WinGet, idList, list, Logged In as, , PokerStars Lobby
Loop, %idList%
{
winID := idList%a_index%
CR_ReloadStarsTable(winID)
}
}

CR_ReloadStarsTable(winID)
{
WinActivate, ahk_id %winID%
CR_PostLeftClick(400, 80, winID)

SetTitleMatchMode, 2
WinWait, Options, Add More Chips, 3
WinGet, winID, ID, Options, Add More Chips
if (winID = "")
return
if CR_ButtonDisabled(winID,"Button5")
return
ControlFocus, Button5, ahk_id %winID%
SendInput {SPACE}

stopTime := A_Now
EnvAdd, stopTime, 5, seconds
loop
{
IfWinExist, PokerStars, Your rebuy cannot be processed
{
WinClose, PokerStars, Your rebuy cannot be processed
return
}
IfWinExist, Buy-in, Allowed maximum
break
if (A_Now > stopTime)
return
}

WinGet, winID, ID, Buy-in, Allowed maximum
if (winID = "")
return

if CR_ButtonDisabled(winID, "Button2")
return
ControlFocus, Button2, ahk_id %winID%
SendInput {SPACE}
sleep, 100

if CR_ButtonDisabled(winID, "Button4")
return
ControlFocus, Button4, ahk_id %winID%
SendInput {SPACE}
sleep, 300

IfWinExist, PokerStars, Your stack will be updated when the current hand is finished
WinClose, PokerStars, Your stack will be updated when the current hand is finished
}

CR_ButtonDisabled(winID, buttonName)
{
ControlGet, result, Enabled, , %buttonName%, ahk_id %winID%
if (result = false)
WinClose, ahk_id %winID%
return (result=false)
}

CR_PostLeftClick(x, y, table_id)
{ ; ### JUK: Send the down left click, then the mouse-up messages.
; NOTE: This is relative to the top left of the client area and NOT the top left of the
; window (ie: It *doesn't* include the title-bar like AHK's MouseClick does!!!).
Postmessage 0x201, 0x0001, ((y*65536)+x), , ahk_id%table_id%
Postmessage 0x202, 0, ((y*65536)+x), , ahk_id%table_id%
}

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; scriptpad ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

CR_Scriptpad_End:
; Do nothing. This is needed to work with Scriptpad.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Code ends here ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

You will probably need to do something wth notepad or something to get the "wrap" workign correctly

cheers

trevor

[aislephive]

Awesome, that works like a charm. Ty.

[DeathbySuckout]

Anybody have this script working at Stars yet? [img]/images/graemlins/frown.gif[/img]

[poisonxfree]

[ QUOTE ]
Anybody have this script working at Stars yet? [img]/images/graemlins/frown.gif[/img]

[/ QUOTE ]

As other said it works if you flick options first, but I'd like to not have to.

[Boquense]

I'm getting same problem, this reloader would be really useful.

[TJD]

Hi Adde,

This is an excellent script working flawlessly at PP even though attempting to reload manually using PP sometimes creates a problem [img]/images/graemlins/smile.gif[/img]

As far as you know would similar methods work with Prima, Tribeca or OnGame?

I am considering opening accounts there but would really like ChipReloader to work as well.

Have you looked at these to see whether it is possible?

If not, I need not bother checking it myself need I? No point in re-inventing the wheel [img]/images/graemlins/smile.gif[/img]

Cheers. TYIA

Trevor

[kittles01]

It works fine on Stars. The problem is that different themes require the click to occur in different locations. You will need to find the correct location for your theme and edit the script following the instructions posted earlier in the thread.

Instructions

[Adde]

All,

I've kind of taken my hands off of this script. The problem is that I don't ever use the script myself (never play NL), don't play at Party anymore and never have played at Stars any much. Also, given the frequent client upgrades that break the code, and new features like Themes making it hard to get a single working script, I don't have them time to update it anymore.

Though, as it seems, there are plenty of people using the script that also know AHK, so they should be able to help out I think.

Adde

[teddyFBI]

Guys:

As mentioned by TJD earlier in this thread, Party seems to have changed something, and the script posted at overcards.com needs to be altered in the following manner:

There are 2 instances of AfxWnd421 that need to be changed to AfxWnd42u1 -- just do a Ctrl-F in your text editor to find them.


If anyone knows how to get the guys at overcards to change the script so that it works at party, link them to this post.